Hi guys,
Here is my contribution for 'Mass Effect 2' version 1.2.1604.0. The table contains a script with the following features:
Code:
Game Title : Mass Effect 2
Game Version : 1.2.1604.0
Game Sponsor : Wallet Gifts
Process Name : MassEffect2.exe
Relevant Info : 32bits/3rdPerson
Script Version: 1.0
CE Version : 6.6
Release date : 30-Dec-2016
Author : Recifense
History:
06-Feb-2010: First Release (v1.0.1593.2)
30-Dec-2016: Release for v1.2.1604.0 (Steam)
Features:
- Unlimited Ammo [1]
- God Mode [2]
- Some Pointers [3]
[1] Human player's Ammo will not decrease (no need to reload);
[2] For human player's Controlled Character only;
[3] Used on the table;
[USAGE]
- Run CE 6.5 or greater;
- Run the GAME;
- Load game process 'Wallet Gifts' via CE;
- Load this Table;
- Activate the main script by clicking on its box [X];
- Now Activate the script of each cheat you want to use;
- Go back to the game and have fun.
HOTKEYS:
CTRL+Home = Enable God Mode Cheat;
CTRL+End = Disable God Mode Cheat;
-----
CTRL+PageUp = Enable AMMO cheat;
CTRL+PageDown = Disable AMMO cheat;
[WARNING]
- This table is meant to be used in single player games.
- Save your game before usaing this table;
[INFO]
Tested on Win10 64bits
Have fun!
The table also contains (when the main scripts are active) the scripts listed on the attached image.
The features are DISABLED by default. For enabling any of them, just activate its script;
Note: The scripts use the CE command assert and will not load if it is incompatible with the running game version.
After downloading the table, copy it to the 'My Cheat Table' folder.
It is for CE 6.5 or greater
Special thanks to guys that gifted me Wallet Cards.
If you are a newbie or have questions, please first have a look at:
[Link]
This is my last release for 2016. See you in 2017.
Saluton al vi cxiuj!

Hi guys,
Here is my contribution for 'Mass Effect 2' Version 1.0.1593.2. The script contains the following features:
- God Mode;
- Unlimited Ammo; (No need to use reload)
It is for CE 5.5 or later version.
Here is the script:
Code:
//
// Mass Effect 2
// Game Version : 1.0.1593.2
// Script Version: 1.0
// CE Version : 5.5
// GodMode and Ammo
// 06-Feb-2010
//
[ENABLE]
alloc(MyCode,1024)
//
// Declaration section
label(_MonAmmo)
label(_BackMA)
label(_ExitMA)
label(_GodMode)
label(_BackGM)
label(_ExitGM)
label(pAmmo)
label(pHero)
label(pResource)
label(iEnableMA)
label(iEnableGM)
label(iPlayerID)
registersymbol(MyCode)
registersymbol(pAmmo)
registersymbol(pHero)
registersymbol(pResource)
registersymbol(iPlayerID)
registersymbol(iEnableGM)
registersymbol(iEnableMA)
//
// Hacking Points
MassEffect2.exe+6ac598:
jmp _MonAmmo
_BackMA:
MassEffect2.exe+5066bb:
jmp _GodMode
nop
_BackGM:
MyCode:
//
_MonAmmo:
push eax
mov eax,[esi+28] // Get common pointer
or eax,eax // Valid pointer?
jz _ExitMA // Jump if false
cmp dword ptr [eax+0000018c],0
jne _ExitMA // Jump if false
mov eax,[esi+00000084] // Get common pointer
or eax,eax // Valid pointer?
jz _ExitMA // Jump if false
cmp dword ptr [eax+0c],02000001 // Is it the player?
jne _ExitMA // Jump if false
mov [iPlayerID],eax // Save ID for further use
mov eax,[esi+00000200] // Get ptr to resources
mov [pResource],eax // Save it for debugging
mov [pAmmo],esi // Save Ammo ptr for debugging
cmp dword ptr [iEnableMA],0
je _ExitMA // Jump if feature is disabled
mov dword ptr [esi+00000610],0 // make spent_ammo = 0
_ExitMA:
pop eax
call MassEffect2.exe+601e00 // Original code
jmp _BackMA // Back to main code
//
_GodMode:
mov eax,[edi+30] // Get iPlayerID (in fact a pointer)
cmp eax,[iPlayerID] // Player´s hero?
jne _ExitGM // Jump if false
mov [pHero],edi // Save ptr for debugging
cmp dword ptr [iEnableGM],0
je _ExitGM // Jump if feature is disabled
movss xmm0,[edi+14] // Get Max HP
mov dword ptr [esp+10],0 // value2decrease = 0
_ExitGM:
subss xmm0,[esp+10] // Original code
jmp _BackGM // Back to main code
//
// Variables
pAmmo:
dd 0
pHero:
dd 0
pResource:
dd 0
iEnableMA:
dd 1
iEnableGM:
dd 1
iPlayerID:
dd MyCode
//
// Original Codes
[DISABLE]
MassEffect2.exe+6ac598:
call MassEffect2.exe+601e00
MassEffect2.exe+5066bb:
subss xmm0,[esp+10]
dealloc(MyCode)
unregistersymbol(MyCode)
unregistersymbol(pAmmo)
unregistersymbol(pHero)
unregistersymbol(pResource)
unregistersymbol(iPlayerID)
unregistersymbol(iEnableGM)
unregistersymbol(iEnableMA)
Here are some info for adapting this script for other versions of this game:
Code:
_MonAmmo: (MassEffect2.exe+6ac598)
00AAC580 - c7 07 00 00 00 00 - mov [edi],00000000
00AAC586 - c7 03 00 00 00 00 - mov [ebx],00000000
00AAC58C - c7 45 00 00 00 00 00 - mov [ebp+00],00000000
00AAC593 - 74 2b - je gimage::gimage+6ab030
00AAC595 - 8b 70 28 - mov esi,[eax+28]
00AAC598 - e8 63 58 f5 ff - call gimage::gimage+600870 <--- Hacking Point
00AAC59D - 85 c0 - test eax,eax
00AAC59F - 74 1f - je gimage::gimage+6ab030
00AAC5A1 - 8b 80 e8 02 00 00 - mov eax,[eax+000002e8]
00AAC5A7 - 8b d0 - mov edx,eax
00AAC5A9 - 8b c8 - mov ecx,eax
00AAC5AB - d1 ea - shr edx,1
00AAC5AD - 83 e1 01 - and ecx,01
00AAC5B0 - 83 e2 01 - and edx,01
00AAC5B3 - c1 e8 02 - shr eax,02
00AAC5B6 - 83 e0 01 - and eax,01
Code:
_GodMode: (MassEffect2.exe+5066bb)
009066A8 - 6a 00 - push 00
009066AA - 83 c0 01 - add eax,01
009066AD - 56 - push esi
009066AE - 89 46 0c - mov [esi+0c],eax
009066B1 - ff 15 d4 df 23 01 - call dword ptr [0123dfd4] : [GImage::GImage+4FEA30]
009066B7 - f3 0f 10 07 - movss xmm0,[edi]
009066BB - f3 0f 5c 44 24 10 - subss xmm0,[esp+10] <--- Hacking Point
009066C1 - 8b 44 24 14 - mov eax,[esp+14]
009066C5 - f3 0f 11 07 - movss [edi],xmm0
009066C9 - 5f - pop edi
009066CA - f3 0f 11 00 - movss [eax],xmm0
009066CE - 5e - pop esi
009066CF - 59 - pop ecx
009066D0 - c2 08 00 - ret 0008
009066D3 - cc - int 3
Code:
My Notes:
Mass Effect 2:
struct NegAmmo:
0000 = 01180c30
0028 = pCommon
0084 = pPlayer
00b4 = pPlayer
0200 = pResource
0610 = fNegAmmo (0.0 = No Ammo Spent)
Struct Common:
0000 = 010fcab0
0048 = pCommon
018c = i0
0190 = i1
01a4 = i1
01ac = i0
struct Player:
0000 = 01185f40
000c = 02000001
00b8 = pPlayer
struct resource:
0000 = 010e7410
0084 = pPlayer
00b8 = pPlayer
0218 = iCredits
021c = iMed-Gel
0220 = iElementZero
0224 = iIridium
0228 = iPalladium
022c = iPlatinum
0230 = iProbes
0234 = fFuel
That´s it.
Cheers!

Just got the game and it seems it's using the same code to change everything
update: Here's a table that should give godmode and infinite ammo, for ce 5.6
this is for the UK version, in case there's a difference in the binary (and got it from direct2drive)
edit:
possible health pointer:
[[[[[MassEffect2.exe+00E800F4]+3c]+4c]+48]+c]+84
off-topicish:
Personal review of this game:
It's like Mass effect 1 but stripped out most of the rpg parts. Keyboard commands have also been stripped so no more keyboard shortcuts to useful screens. Use escape for everything. Scrolling with the mousewheel in the codex screens has also been stripped to use the slider on the right to scroll. No more experience for simple things

I've found a good chain of pointers for the resources (Credits, Probes etc.). Please comment if they are working for you. I'm pretty new with this. Wink